// CUE definitions for the eventual output dictionary
package shenikan

_vowels: ["i", "e", "a", "o", "u"]
#VowelAttribute:   "outer" | "slashed" | "inner"
#ClusterAttribute: "left" | "center" | "right" | "top" | "middle" | "bottom" |
			"tall" | "wide" | "both"
#PunctuationAttribute: "left" | "right"
#NumericAttribute:     "circle" | "dash" | "vee" | "hump" | "dot"
#SyllableAttribute:    #VowelAttribute | #ClusterAttribute

#Glyph: #VowelGlyph | #ClusterGlyph | #PunctuationGlyph | #NumericGlyph |
	#SyllableGlyph

#VowelGlyph: {kind: "vowel", ortho: string, attrs: [...#VowelAttribute]}
#ClusterGlyph: {kind: "cluster", ortho: string, attrs: [...#ClusterAttribute]}
#PunctuationGlyph: {kind: "punctuation", ortho: string, attrs: [...#PunctuationAttribute]}
#NumericGlyph: {kind: "numeric", ortho: string, attrs: [...#NumericAttribute]}
#SyllableGlyph: {kind: "syllable", ortho: string, attrs: [...#SyllableAttribute]}

#Replacement: {
	old: string
	new: string
}
#Dialect: {
	name: string
	replacements: [...#Replacement]
}

#PartOfSpeech: "noun" | "pronoun" | "verb" | "adjective" | "adverb" | "adposition" | "conjunction" | "syntax"
#Definition: {
	pos:   #PartOfSpeech
	short: string
	long?: string
}
#DerivationalMorphology: {
	spelling: string
	definitions: [...#Definition]
}
#DMPenta: {
	spelling: string
	name?:    string
	extremes?: {
		i?: string
		u?: string
	}
}
#Derivation: {
	root: string
	via: [...string]
}
#Word: {
	spelling: string
	definitions: [...#Definition]
	derivations: [...#Derivation]
}

#Penta: {
	spelling: string
	name?:    string
	extremes?: {
		i?: string
		u?: string
	}
}

#Icosa: {
	spelling: string
	name?:    string
	extremes?: {
		ix?: string
		ux?: string
		xi?: string
		xu?: string
	}
}

dictionary: {
	glyphs: [...#Glyph]
	dialects: [...#Dialect]
	dms: [...#DerivationalMorphology]
	dmPentas: [...#DMPenta]
	words: [...#Word]
	pentas: [...#Penta]
	icosas: [...#Icosa]
}